Quote:
Originally Posted by SimonKilmore
This is what my current input looks like, but it's not working, so something can't be right.
ffmpeg -i input.ts -aspect 16:9 -f m2v -s 720x576 -b 67108864 -an video.m2v
I used this docmentation to get this -
ffmpeg.mplayerhq.hu/ffmpeg-doc.html
Thanks
|
When you say its not working, what do you mean?
Here's the batch file line I use to go from .tp or .ts to .mpg. Its based on what HDTV2DVD uses. NOTE: some of the lines have wrapped. You'll have to modify the path to your copy of ffmpeg.exe.
::batch process MPG from TP
::Parameters - all parameters must be enclosed in quotes
:: %1=full path to .TP file
:: %2=full path to .MPG file for output
:: %3=desired average bit rate (defaults to 3000)
:: %4=desired max bit rate (defaults to 7800)
::Examples:
:: call hdtompg.bat "d:\dvr\bones\28 - The Girl in Suite 2103.tp" "C:\dvr\bones\28 - The Girl in Suite 2103.mpg" "3000" "7800"
:: call hdtompg.bat "d:\dvr\smallville\128 - Progeny.tp" "d:\dvr\smallville\128 - Progeny.mpg" "" ""
ECHO OFF
set HDTV2DVD="C:\Program Files\BadgerIT\HDTV2DVD"
set FFMPEG="%HDTV2DVD:~1,-1%\ffmpeg.exe"
set SOURCETP=%1
set SOURCETP=%SOURCETP:~1,-1%
set TARGETMPG=%2
set TARGETMPG=%TARGETMPG:~1,-1%
set BITRATE=%3
IF NOT '%BITRATE%' == '' set BITRATE=%BITRATE:~1,-1%
IF "%BITRATE%" == "" set BITRATE=3000
set MAXBITRATE=%4
IF NOT '%MAXBITRATE%' == '' set MAXBITRATE=%MAXBITRATE:~1,-1%
IF "%MAXBITRATE%" == "" set MAXBITRATE=6000
set FFMPEG_PASSLOG=c:\temp\ffmpeg.log
set FRAMERATE=30000/1001
set INTRA_MATRIX=08,08,09,11,13,13,14,17,08,08,11,12,1 3,14,17,18,09,11,13,13,14,17,17,19,11,11,13,13,14, 17,18,20,11,13,13,14,16,17,20,24,13,13,14,16,17,20 ,24,29,13,13,14,17,19,23,28,34,13,14,17,19,23,28,3 4,41
set INTER_MATRIX=08,08,08,09,09,09,09,10,08,08,09,09,0 9,09,10,10,08,09,09,09,09,10,10,10,09,09,09,09,10, 10,10,10,09,09,09,10,10,10,10,11,09,09,10,10,10,10 ,11,11,09,10,10,10,10,11,11,11,10,10,10,10,11,11,1 1,11
set STUFF=-mbd 2 -qmin 1 -mblmin 1 -lmin 1 -qsquish 1 -rc_init_cplx 500 -padtop 0 -padbottom 0 -async 50 -flags2 +sgop -deinterlace
:downsample the TP file using ffmpeg
%FFMPEG% -i "%SOURCETP%" -y -target ntsc-dvd -acodec copy -intra_matrix %INTRA_MATRIX% -inter_matrix %INTER_MATRIX% -r %FRAMERATE% -bf 2 -b %BITRATE% -maxrate %MAXBITRATE% -s 720x480 %STUFF% -pass 1 -passlogfile "%FFMPEG_PASSLOG%" "%TARGETMPG%"
%FFMPEG% -i "%SOURCETP%" -y -target ntsc-dvd -acodec copy -intra_matrix %INTRA_MATRIX% -inter_matrix %INTER_MATRIX% -r %FRAMERATE% -bf 2 -b %BITRATE% -maxrate %MAXBITRATE% -s 720x480 %STUFF% -pass 2 -passlogfile "%FFMPEG_PASSLOG%" "%TARGETMPG%"